3

Take google images, flickr photostream, etc. as exmaples. Each image has different dimensions+radios but they all line up on the left + right sides.

My original logic was to loop through them in javascript, figure out when I'm at the point where the next image is too wide. Then I see how much "room" I have and add width across the board - but I end up making thin images too wide.

something LIKE this is what I was doing:

maxwidth = 100;
width = 0;
imgs = [];
foreach image {
    if (width + image.width > maxwidth) {
        space = maxwidth - width / imgs.length;
        foreach imgs {
            img.width = img.width + space;
        }

        imgs = [];
        width = 0;
    }

    imgs.push(image);
    width += image.width;
}
Kaitlyn2004
  • 3,879
  • 4
  • 16
  • 16

1 Answers1

1

This is the partition problem; its application to photo galleries is discussed in this blog post by Johannes Treitz. The suggested solution is:

  • To find k, the number of rows needed, scale the photos to half the window's height, sum up their widths, divide by the window's width, and then round.
  • The photos' aspect ratios then serve as a set S of weights. Find the optimal distribution of S over k using an existing linear partition algorithm.

The blog post includes the following CoffeeScript to build the gallery:

viewport_width = $(window).width()
ideal_height = parseInt($(window).height() / 2)
summed_width = photos.reduce ((sum, p) -> sum += p.get('aspect_ratio') * ideal_height), 0
rows = Math.round(summed_width / viewport_width)

if rows < 1
  # (2a) Fallback to just standard size 
  photos.each (photo) -> photo.view.resize parseInt(ideal_height * photo.get('aspect_ratio')), ideal_height
else
  # (2b) Distribute photos over rows using the aspect ratio as weight
  weights = photos.map (p) -> parseInt(p.get('aspect_ratio') * 100)
  partition = linear_partition(weights, rows)

  # (3) Iterate through partition
  index = 0
  row_buffer = new Backbone.Collection
  _.each partition, (row) ->
    row_buffer.reset()
    _.each row, -> row_buffer.add(photos.at(index++))
    summed_ratios = row_buffer.reduce ((sum, p) -> sum += p.get('aspect_ratio')), 0
    row_buffer.each (photo) -> photo.view.resize parseInt(viewport_width / summed_ratios * photo.get('aspect_ratio')), parseInt(viewport_width / summed_ratios)

The linear_partition function is implemented as follows (see github):

# Linear partition
# Partitions a sequence of non-negative integers into k ranges
# Based on Óscar López implementation in Python (http://stackoverflow.com/a/7942946)
# Also see http://www8.cs.umu.se/kurser/TDBAfl/VT06/algorithms/BOOK/BOOK2/NODE45.HTM
# Dependencies: UnderscoreJS (http://www.underscorejs.org)
# Example: linear_partition([9,2,6,3,8,5,8,1,7,3,4], 3) => [[9,2,6,3],[8,5,8],[1,7,3,4]]

linear_partition = (seq, k) =>
  n = seq.length

  return [] if k <= 0
  return seq.map((x) -> [x]) if k > n

  table = (0 for x in [0...k] for y in [0...n])
  solution = (0 for x in [0...k-1] for y in [0...n-1])
  table[i][0] = seq[i] + (if i then table[i-1][0] else 0) for i in [0...n]
  table[0][j] = seq[0] for j in [0...k]
  for i in [1...n]
    for j in [1...k]
      m = _.min(([_.max([table[x][j-1], table[i][0]-table[x][0]]), x] for x in [0...i]), (o) -> o[0])
      table[i][j] = m[0]
      solution[i-1][j-1] = m[1]

  n = n-1
  k = k-2
  ans = []
  while k >= 0
    ans = [seq[i] for i in [(solution[n-1][k]+1)...n+1]].concat ans
    n = solution[n-1][k]
    k = k-1

  [seq[i] for i in [0...n+1]].concat ans
sjy
  • 2,702
  • 1
  • 21
  • 22