Source of my syntax error

Question

I'm learning Haskell and been writing an example program from a book. This module below won't compile and gives me the following error in ghci and ghc:

"Optimal.hs:15:23: parse error on input ‘=’"

Any ideas, I can't see it?

---

module Optimal (optimalPath) where

import RoadSystem

optimalPath :: RoadSystem -> Path
optimalPath roadSystem =
    let (bestAPath, bestBPath) = foldl roadStep ([], []) roadSystem
    in if sum (map snd bestAPath) <= sum (map snd bestBPath)
            then reverse bestAPath
            else reverse bestBPath

roadStep :: (Path, Path) -> Section -> (Path, Path)
roadStep (pathA, pathB) (Section a b c) =
    let timeA = sum (map snd pathA)
        timeB = sum (map snd pathB)
        forwardTimeToA = timeA + a
        crossTimeToA = timeB + b + c
        forwardTimeToB = timeB + b
        crossTimeToB = timeA + a + c
        newPathToA = if forwardTimeToA <= crossTimeToA
                        then (A, a):pathA
                        else (C, c):(B, b):pathB
        newPathToB = if forwardTimeToB <= crossTimeToB
                        then (B, b):pathB
                        else (C, c):(A, a):pathA
    in (newPathToA, newPathToB)

Answer 1

Any ideas, I can't see it?

This is what happens when you use tabs for indentation. The Haskell standard mandates to assume a tabstop of 8 characters, so the compiler is actually thinking that your code is:

module Optimal (optimalPath) where

import RoadSystem

optimalPath :: RoadSystem -> Path
optimalPath roadSystem =
        let (bestAPath, bestBPath) = foldl roadStep ([], []) roadSystem
        in if sum (map snd bestAPath) <= sum (map snd bestBPath)
                then reverse bestAPath
                else reverse bestBPath

roadStep :: (Path, Path) -> Section -> (Path, Path)
roadStep (pathA, pathB) (Section a b c) =
        let timeA = sum (map snd pathA)
                timeB = sum (map snd pathB)
                forwardTimeToA = timeA + a
                crossTimeToA = timeB + b + c
                forwardTimeToB = timeB + b
                crossTimeToB = timeA + a + c
                newPathToA = if forwardTimeToA <= crossTimeToA
                                                then (A, a):pathA
                                                else (C, c):(B, b):pathB
                newPathToB = if forwardTimeToB <= crossTimeToB
                                                then (B, b):pathB
                                                else (C, c):(A, a):pathA
        in (newPathToA, newPathToB)

And sure enough near line 15, character 23 you have:

        let timeA = sum (map snd pathA)
                timeB = sum (map snd pathB)

which is a syntax error.

To fix it:

• Don't use tabs for indentation. Every editor allows you to configure the tab key to insert a configurable number of spaces instead of one tab, so there's no "I have to press the space bar many times" problem.
• _{Use a tabstop of 8 in your editor. Note that if you send code to someone else he might have the same problem when modifying the code.}