Why does adding or removing a newline change the way this perl for loop functions?

Question

I'm starting to learn perl, using the Wrox Beginning Perl available on perl.org and have a question regarding a for loop example they provide in Chapter 3.

#!/usr/bin/perl

use warnings;
use strict;

my @count = (1..10);
for (reverse(@count)) {
        print "$_...\n";
        sleep 1;
}
print "Blast Off!\n"

This is the script they provide, and it works as expected. It displays a number followed by ... every second, waiting a second in between each number. When done, it displays Blast Off!

However if I remove the newline from the print statement, the behaviour changes. The script silently waits 10 seconds and then displays all 10 numbers and Blash Off! at once. Why the change?

#!/usr/bin/perl

use warnings;
use strict;

my @count = (1..10);
for (reverse(@count)) {
        print "$_...";
        sleep 1;
}
print "Blast Off!\n"

Output to STDOUT is buffered by default. Do "perldoc perlvar" and look for $| — xcramps, Aug 10 '10 at 01:55
For more fun try `print "$_... \r` ( after setting autoflush ); — Brad Gilbert, Aug 11 '10 at 19:19

score 11 · Accepted Answer · answered Aug 10 '10 at 01:55

11

Perl is buffering the print output and the buffer isn't flushed until the newline. Alternatively, you can add $| = 1 before your loop to tell Perl to flush the buffer between the print statements, thus giving you the expected output with the proper delay:

#!/usr/bin/perl

use warnings;
use strict;

$| = 1; #Add this line
my @count = (1..10);
for (reverse(@count)) {
        print "$_...";
        sleep 1;
}
print "Blast Off!\n"'

answered Aug 10 '10 at 01:55

eldarerathis

35,455
10
90
93

The way I did it, with the select statements, is safer if there is any other file interaction. – Paul Tomblin Aug 10 '10 at 11:21
2

Even better, and more modern: use IO::Handle; STDOUT->autoflush(1); – mscha Aug 10 '10 at 11:37

Paul Tomblin · Answer 2 · 2010-08-11T19:04:42.950

Standard output is line buffered. It won't flush the buffer until it sees a newline. You can correct this by adding the following line before the loop:

my $ofh = select(STDOUT); $| = 1; select $ofh;

Let's break that down:

my $ofh = select(STDOUT); - selects the STDOUT (standard output) as the current selected file handle, and stores whatever was the previous selected file handle in $ofh

$| = 1; - sets the current file handle (ie. STDOUT) to unbuffered.

select $ofh; - reselects whatever was the selected file handle before, so that if the code had selected a file handle other than STDOUT at some point, it will still be selected after this line of code is finished.

You should probably explain what the `select`s are for. – Brad Gilbert Aug 11 '10 at 18:59 — Brad Gilbert, Aug 11 '10 at 18:59

score 4 · Answer 3 · answered Aug 10 '10 at 01:55

4

You are looking at the standard behavior of the line-oriented output of the C stdio library when writing to a terminal.

See autoflush for perl details.

answered Aug 10 '10 at 01:55

msw

42,753
9
87
112

score 1 · Answer 4 · answered Aug 10 '10 at 12:38

1

A neater way than using select() to set the autoflush flag on STDOUT is to use IO::Handle (which has been included with the Perl core since version 5.004):

use IO::Handle;
STDOUT->autoflush(1)

answered Aug 10 '10 at 12:38

ilmari

301
1
3

Why does adding or removing a newline change the way this perl for loop functions?

4 Answers4

Linked