Delphi TImage: How do I display images that are larger than the TImage component they are being loaded in or assigned to?

Question

Some JPEG files with the following formats aren't displaying in Delphi's TImage control.

• issue resolved.. [TImage.Autosize] Checkbox in image control is not checked by default, and as a result the image wasn't resizing. I was working with this project.. https://community.embarcadero.com/blogs/entry/converting-to-grayscale-with-tbitmapscanline-property-39051

and comparing the speed to my existing grayscale code. The scanline process they use appears to be slightly faster than the scanline process that I currently have in place. It is a great starting point for someone working with images. I added the standard jpeg conversion code and scrollboxes when I ran into the issue and noticed the file size. I believe the question was valid, but I reworded it. If I find another related answer where the question is easier to find, I will pull this post. If not, I will leave it.

For example, from a Nikon digital camera.

Dimensions : Width 5184 x Height 3888
Vertical Resolution : 300 dpi
Color Representation : sRGB
Compressed bits/pixel : 2
Bit depth : 24
EXIF version : 0230
Attributes : N

From a Samsung cell phone camera:

Dimensions : Width 4128 x Height 2322
Horizontal & Vertical Resolution : 72 dpi
Color Representation : sRGB
Resolution unit : 2
Compressed bits/pixel : [blank]
Bit depth : 24
EXIF version : 0220
Attributes : A

A grayscale file from Adobe Photoshop:

Dimensions : Width 1800 x Height 3600
Horizontal and Vertical Resolution : 300 dpi
Color Representation : Uncalibrated
Compressed bits/pixel : [blank]
Bit depth : 8
EXIF version : [blank]
Attributes : A

A file with the exact format as the last one, but with much smaller dimensions, works.

Dimensions of one working file : Width 570 x Height 248

Files with 24-bit depth, smaller dimensions, and no resolution or compression settings, work correctly as well.

When I try to display the pictures using the code below, the picture on the failing files is always blank, and no errors are returned. It works perfectly with many other jpg and bmp files.

Is there a conversion that is required for sRGB formatted files? Is there a size limit on what the control can display on screen? If so, is there a way to display larger files?

procedure TForm1.btnBrowseClick(Sender: TObject);
var
  bmp: TBitmap;
  c2g: TColor2Grayscale;
  ba: TBitmapAccess;
  sw: TStopwatch;
  jpg : TJPEGImage; // jpeg does not show 32-bit support in Delphi, only 24 and 8.
  path, name, ext : string;
  alreadyGray : boolean;
begin
  bmp := TBitmap.Create;
  jpg := TJPEGImage.Create;

  OpenPicturedialog1.InitialDir := FindImageFolder(true);
  if OpenPictureDialog1.Execute() then
  try
    name := OpenPictureDialog1.FileName;
    path := ExtractFilePath(name);
    ext := Lowercase ( ExtractFileExt(name) );

    alreadyGray := false;

    try
      if ( ext = '.jpg' ) or ( ext = '.jpeg' ) then
      begin
        jpg.LoadFromFile(name);
        bmp.Assign(jpg);
        alreadyGray := jpg.Grayscale;
      end
      else
        bmp.LoadFromFile( name );
    except
      on err: Exception do
      begin
        ShowMessage(err.Message);
        Exit;
      end;
    end;

    if bmp.PixelFormat = pfDevice then
      bmp.PixelFormat := pf32bit;

    Image1.Picture.Assign(bmp);

    if alreadyGray then
    begin
      Image2.Picture.Assign(bmp);
      Exit;
    end;

  finally
    jpg.Free;
    bmp.Free;
  end;
end;

Answer 1

Since you are not getting an error when loading the JPEG image, I suspect the problem may be in the conversion from TJPEGImage to TBitmap. Unless you are going to be manipulating the image pixels, you don't need the conversion at all, you can assign the original TJPEGImage directly to the TImage. The VCL's TPicture class uses derived TGraphic classes so it can display images in their native formats, you should utilize that feature, eg:

procedure TForm1.btnBrowseClick(Sender: TObject);
var
  jpg: TJPEGImage;
  bmp: TBitmap;
begin
  OpenPicturedialog1.InitialDir := FindImageFolder(true);
  if OpenPictureDialog1.Execute then
  begin
    Image1.Picture.LoadFromFile(OpenPictureDialog1.FileName);

    if Image1.Picture.Graphic is TJPEGImage then
    begin
      if TJPEGImage(Image1.Picture.Graphic).Grayscale then
      begin
        Image2.Picture.Assign(Image1.Picture.Graphic);
      end else
      begin
        jpg := TJPEGImage.Create;
        try
          jpg.Assign(Image1.Picture.Graphic);
          jpg.Grayscale := True;
          Image2.Picture.Assign(jpg);
        finally
          jpg.Free;
        end;
      end;
    end else
    begin
      bmp := TBitmap.Create;
      try
        bmp.PixelFormat := pf32bit;
        bmp.Assign(Image1.Picture.Graphic);
        ...
        Image2.Picture.Assign(bmp);
      finally
        bmp.Free;
      end;
    end;
  end;
end;

---

Update: I did some tests in XE2 on Windows 7, and saw the same issue you do.

If I load the JPGs as-is using TImage.Picture.LoadFromFile(), they display fine only if the TImage.Stretch or TImage.Proportional property is True. If they are both set to False (the default), the images display blank.

If I load the JPGs into TJPEGImage first and then assign that to TBitmap, the conversion itself works fine (proved by saving the TBitmap to a .bmp file), and the bitmaps are displayed fine only if Stretch or Proportional are True, otherwise they display blank.

So, as another test, I tried using TPaintBox, drawing the images manually in its OnPaint event. If I use TCanvas.Draw() to draw the images as-is in their full dimensions, they display empty. If I use TCanvas.StretchDraw() to fit the images within the `PaintBox's client area, they display fine.

So, I think TCanvas is likely running into memory issues trying to display images at such larger dimensions. It has nothing to do with the particular type of JPGs being used (which are being loaded fine).

---

Update: nevermind what I said above. I see that the provided JPGs just have really large DPIs and happen to all be white in their top-left corners. If the TImage/TPaintBox is sized large to compensate, I can now see the images in their full dimensions (it is easier to see if the TImage is placed on a TScrollBox with TImage.AutoSize set to True). That would explain why stretch/proportional drawing works, by stretching the images to match TImage's dimensions when needed.